#SingleInstance force
#WinActivateForce

; define
DATA_FILE := "デスクトップの表示.dat"
DESKTOP_CLASS := "ahk_class Progman"
POPUP1_CLASS := "XamlExplorerHostIslandWindow_WASDK"
POPUP2_CLASS := "WorkerW"

; ----------------------------------------
; helper function
; ----------------------------------------

getString(hwndList) {
    ret := ""
    for index, value in hwndList
        ret .= "|" . value
    return LTrim(ret, "|")
}

restoreWindow(hwndList, statusList) {
    for index, value in hwndList {
        reverseIndex := hwndList.Length - index + 1
        hwnd := Integer(hwndList[reverseIndex])
        if WinExist(hwnd)
            if (statusList[reverseIndex] != -1) ; skip minimize window
                WinActivate(hwnd)
    }
}

; ----------------------------------------
; duplicate run
; ----------------------------------------

if FileExist(DATA_FILE) {
    ; read data file
    FileObj := FileOpen(DATA_FILE, "r")
    hwndString := FileObj.ReadLine()
    hwnd := StrSplit(hwndString, "|")
    statusString := FileObj.ReadLine()
    status := StrSplit(statusString, "|")

    ; restore window
    restoreWindow(hwnd, status)

    ; delete data file
    FileDelete(DATA_FILE)

    ; exit
    ExitApp
}

; ----------------------------------------
;  main process
; ----------------------------------------

; get window handles for restore
hwnd := WinGetList()

; get window status
status := []
for index, value in hwnd
    status.Push(WinGetMinMax(value))

; creat data file
FileAppend(getString(hwnd), DATA_FILE)
FileAppend("`n", DATA_FILE)
FileAppend(getString(status), DATA_FILE)
FileAppend("`n", DATA_FILE)

; show desktop and focus
Send "#d"
Sleep 1000
hwndDesktop := WinGetID(DESKTOP_CLASS)
ControlFocus(hwndDesktop)

; get window handles for monitoring
hwnd1 := WinGetList()

; wait new window
WinWaitNotActive WinExist("A")
Loop {
    Sleep 500
    hwnd2 := WinGetList()
    try {
        className := WinGetClass("A")
        if ((className != POPUP1_CLASS) && (className != POPUP2_CLASS))
            if getString(hwnd1) != getString(hwnd2)
                break
    } catch {
    } finally {
        activeId := WinExist("A")
        hwnd2 := WinGetList()
    }
}

; restore window
restoreWindow(hwnd, status)

; active new window
try {
    WinActivate(activeId)
} catch {
    WinActivate(hwnd2[1])
}

; delete data file
if FileExist(DATA_FILE)
    FileDelete(DATA_FILE)